Server : Apache System : Linux server2.corals.io 4.18.0-348.2.1.el8_5.x86_64 #1 SMP Mon Nov 15 09:17:08 EST 2021 x86_64 User : corals ( 1002) PHP Version : 7.4.33 Disable Function : exec,passthru,shell_exec,system Directory :  /home/corals/old/vendor/magento/magento2-functional-testing-framework/bin/

Upload File : current_dir [ Writeable ] document_root [ Writeable ]

:: Copyright © Magento, Inc. All rights reserved.
:: See COPYING.txt for license details.

@echo off
SETLOCAL EnableDelayedExpansion
SET BLOCKLIST_FILE=bin/blocklist.txt
SET i=0

FOR /F %%x IN ('git ls-tree --full-tree -r --name-only HEAD') DO (
    SET GOOD_EXT=
    if "%%~xx"==".php" set GOOD_EXT=1
    if "%%~xx"==".xml" set GOOD_EXT=1
    if "%%~xx"==".xsd" set GOOD_EXT=1
    IF DEFINED GOOD_EXT (
        SET BLOCKLISTED=
        FOR /F "tokens=* skip=5" %%f IN (%BLOCKLIST_FILE%) DO (
            SET LINE=%%x
            IF NOT "!LINE!"=="!LINE:%%f=!" (
                SET BLOCKLISTED=1
            )
        )
        IF NOT DEFINED BLOCKLISTED (
            FIND "Copyright © Magento, Inc. All rights reserved." %%x >nul
            IF ERRORLEVEL 1 (
                SET /A i+=1
                SET NO_COPYRIGHT_LIST[!i!]=%%x
            )
        )
    )
)

IF DEFINED NO_COPYRIGHT_LIST[1] (
    ECHO THE FOLLOWING FILES ARE MISSING THE MAGENTO COPYRIGHT:
    ECHO.
    ECHO     Copyright © Magento, Inc. All rights reserved.
    ECHO     See COPYING.txt for license details.
    ECHO.
    FOR /L %%a IN (1,1,%i%) DO (
        ECHO !NO_COPYRIGHT_LIST[%%a]!
    )
)